10 REM COPYRIGHT 1987 COMPUTE! PUBLICATIONS INC. - ALL RIGHTS RESERVED
20 PRINT"[147]  COPYRIGHT 1987 COMPUTE! PUB., INC."
30 PRINTTAB(9)"ALL RIGHTS RESERVED"
40 OPEN 15,8,15
50 OPEN 1,8,2,"0:TESTREL"
60 INPUT#15,E,E$,E1,E2
70 IF E=0 GOTO230
80 CLOSE 1
90 IF E<>62 THEN PRINT E;E$;E1;E2:STOP
100 PRINT"CREATING FILE"
110 OPEN 1,8,2,"0:TESTREL,L,"+CHR$(33)
120 INPUT#15,E,E$,E1,E2
130 IF E<>0 THEN CLOSE 1:PRINT E,E$,E1,E2:STOP
140 PRINT#15,"P"+CHR$(98)+CHR$(10)+CHR$(0)+CHR$(1)
150 INPUT#15,E,E$,E1,E2
160 IF E<>50 THEN CLOSE 1:PRINT E;E$;E1;E2:STOP
170 PRINT#1,CHR$(255);
180 INPUT#15,E,E$,E1,E2
190 CLOSE 1
200 IF E<>0 THEN PRINT E;E$;E1;E2:STOP
210 OPEN 1,8,2,"0:TESTREL"
220 GOTO240
230 PRINT"FILE ALREADY EXISTS"
240 PRINT"1. READ ALL RECORDS"
250 PRINT"2. WRITE RECORD"
260 PRINT"3. QUIT"
270 INPUT"WHICH (1, 2 OR 3)";X:PRINT
280 ON X GOTO300,440,710
290 GOTO240
300 R=0
310 R=R+1:F=0:X=0
320 H=INT(R/256):L=R-H*256
330 PRINT#15,"P"+CHR$(98)+CHR$(L)+CHR$(H)+CHR$(1)
340 INPUT#15,E,E$,E1,E2
350 IF E=50 GOTO240
360 IF E<>0 THEN PRINT E;E$;E1;E2:GOTO710
370 INPUT#1,X$:SW=ST
380 IF X$=CHR$(255) THEN PRINT"RECORD";R;"<EMPTY>":GOTO310
390 IF F=0 THEN PRINT"RECORD";R;":"
400 F=F+1:IF SW=0 THEN X=1
410 PRINT"     FIELD";F;": ";X$
420 IF SW=0 GOTO370
430 GOTO310
440 INPUT"WRITE TO RECORD NUMBER";R
450 IF R<1 OR R<>INT(R) GOTO440
460 IF R>40 THEN PRINT "TOO BIG!":GOTO570
470 H=INT(R/256):L=R-H*256
480 PRINT#15,"P"+CHR$(98)+CHR$(L)+CHR$(H)+CHR$(1)
490 INPUT#15,E,E$,E1,E2
500 IF E=50 THEN PRINT"A NEW ONE!"
510 INPUT"HOW MANY FIELDS (1-3)";N
520 IF N<1 OR N>3 GOTO510
530 A$=""
540 PRINT"ENTER DATA:"
550 FOR J=1 TO N
560 IF N<>1 THEN PRINT"FIELD";J;
570 INPUT B$
580 A$=A$+B$+CHR$(13)
590 NEXT J
600 A$=LEFT$(A$,LEN(A$)-1)
610 PRINT#1,A$;
620 INPUT#15,E,E$,E1,E2
630 IF E<>0 THEN PRINT E;E$;E1;E2
640 CLOSE 1
650 INPUT#15,E,E$,E1,E2
660 IF E<>0 THEN PRINT E;E$;E1;E2
670 OPEN 1,8,2,"0:TESTREL"
680 INPUT#15,E,E$,E1,E2
690 IF E<>0 THEN PRINT E;E$;E1;E2
700 GOTO240
710 CLOSE 1
720 CLOSE 15